;http://service1.symantec.com/SUPPORT/ent-security.nsf/docid/2002091816510548?Open&src=&docid=2005040711404048&nsf=ent-security.nsf&view=docid&dtype=corp&prod=&ver=&osv=&osv_lvl=
Dim $result, $size, $percent, $bytesdownloaded, $xdbfilename, $file

WinClose ( 'Old Virus Definition File' )

;C:\Misc\Symantec Antivirus CE\DownloadXDB.exe
If @OSVersion = 'WIN_XP' AND @OSServicePack = 'Service Pack 2' Then
	SplashTextOn ( 'UD ZEN Imaging', 'Allowing updater to work with' & @CRLF & 'XP SP2 Firewall ...', 300, 75 )
	RunWait ( 'netsh firewall set allowedprogram "C:\Misc\Symantec Antivirus CE\DownloadXDB.exe"', '', @SW_HIDE )
	Sleep ( 2500 )
	SplashOff ( )
EndIf

SplashTextOn ( 'UD ZEN Imaging', 'Attempting to download the latest definitions now ...', 300, 50 )

$size = InetGetSize ( 'ftp://ftp.symantec.com/AVDEFS/norton_antivirus/static/navup8.exe' )
If $size = 0 Then
	SplashOff ( )
	MsgBox ( 262144+48, 'UD ZEN Imaging', 'Could not determine size of the virus signature update.  Try ahain later.', 10 )
	Exit
EndIf

$result = InetGet ( 'ftp://ftp.symantec.com/AVDEFS/norton_antivirus/static/navup8.exe', @ScriptDir & '\navup8.exe', 0, 1 )	;background download

If $result = 0 Then
	SplashOff ( )
	MsgBox ( 262144+48, 'UD ZEN Imaging', 'The download of the virus update failed.  Try again later.', 10 )
	Exit
EndIf

ProgressOn ( 'UD ZEN Imaging', 'Downloading newest antivirus definitions', '' )
While @InetGetActive = 1	;while downloading the file
	
	$bytesdownloaded = @InetGetBytesRead
	$percent = ( $bytesdownloaded / $size ) * 100
	$percent = Round ( $percent, 1 )

	ProgressSet ( $percent, $percent & '% complete', 'Downloading update ...' )
	Sleep ( 100 )
WEnd
ProgressOff ( )

SplashTextOn ( 'UD ZEN Imaging', 'Extracting new .XDB file ...', 300, 50 )
RunWait ( @ScriptDir & '\navup8.exe' )
Sleep ( 2500 )
SplashOff ()

$file = FileFindFirstFile ( '*.xdb' )

If $file = -1 Then
	MsgBox ( 262144+48, 'UD ZEN Imaging', 'Problem accessing the .XDB file.  Try again later!', 10 )
	FileClose($file)
	Exit
EndIf

$xdbfilename = FileFindNextFile ( $file )
FileClose($file)

#cs
To copy an .xdb file to a Symantec AntiVirus client

    * Copy the .xdb file to the correct folder, depending on the program version:
          o For clients that run Windows 2003/XP/2000, the default folder is one of the following:
                + C:\Documents and Settings\All Users\Application Data\Symantec\Norton AntiVirus Corporate Edition\7.5\
                + C:\Documents and Settings\All Users\Application Data\Symantec\Symantec AntiVirus Corporate Edition\7.5\

                  The Application Data folder may be hidden. To show hidden and system folders, read the document How to make Windows show all files.
          o For clients that run Windows 98/Me, the following is the default folder:
            C:\Program Files\Symantec_Client_Security\Symantec AntiVirus\ or C:\Program Files\Symantec AntiVirus\
          o For clients that run Windows NT 4.0, the following is the default folder:
            C:\WinNT\Profiles\All Users\Application Data\Symantec\Norton AntiVirus Corporate Edition\7.5\
#ce

$result = FileCopy ( @ScriptDir & '\' & $xdbfilename, @AppDataCommonDir & '\Symantec\Symantec AntiVirus Corporate Edition\7.5\' & $xdbfilename, 1 )
If $result = 0 Then
	MsgBox ( 262144 + 0, 'UD ZEN Imaging', 'File copy failed!', 10 )
	Exit
EndIf

SplashTextOn ( 'UD ZEN Imaging', 'Stopping SAV CE service ...', 300, 50 )
RunWait ( 'net stop "Symantec AntiVirus"' )
Sleep ( 15000 )

SplashTextOn ( 'UD ZEN Imaging', 'Restarting SAV CE service ...', 300, 50 )
RunWait ( 'net start "Symantec AntiVirus"' )
Sleep ( 2500 )