Environment
Novell ZENworks Configuration Management 11.2.4 System Update
Novell ZENworks Asset Management 11.2.4
Novell ZENworks Endpoint Security Management 11.2.4
Novell ZENworks Full Disk Encryption 11.2.4
Novell ZENworks Patch Management 11.2.4
Novell ZENworks Asset Management 11.2.4
Novell ZENworks Endpoint Security Management 11.2.4
Novell ZENworks Full Disk Encryption 11.2.4
Novell ZENworks Patch Management 11.2.4
Situation
Upgrading managed device to ZCM 11.2.4 fails, the following errors are seen in the system-update.log
ERROR;MSI_INSTALL_ERROR;CASA.x86_64.msi,1612;
ERROR;MSI_INSTALL_ERROR;CASA.x86_64.msi,1612;
DEBUG;;;An error occured during command execution...details should have already
been logged
ERROR;MSI_INSTALL_ERROR;CASA.x86_64.msi,1612;
ERROR;MSI_INSTALL_ERROR;CASA.x86_64.msi,1612;
DEBUG;;;An error occured during command execution...details should have already
been logged
Resolution
Workaround
This procedure can also be attempted for any other failures with a 1612 error.
- Create a directory on the affected device, and copy CASA.msi or CASA.x86_64.msi (depending on whether the device is 32-bit or 64-bit) from a primary server that has been successfully upgraded to ZCM 11.2.4
- Linux: /opt/novell/zenworks/install/downloads/msi
Windows: %ZENWORKS_HOME%\install\downloads\msi - in the directory created in step 1, create casa_fix.bat using the code shown in the Additional Information section
- Open a command prompt, change directory to the directory created in step 1 and issue the command
casa_fix casa.msi
or
casa_fix CASA.x86_64.msi
(depending on whether the device is 32-bit or 64-bit)
This procedure can also be attempted for any other failures with a 1612 error.
Cause
1612 indicates that the msi was corrupt.
Additional Information
contents of casa_fix.bat
@echo off
if "A%1A" == "AA" (
echo Usage: casa_fix ^<path to casa MSI^>
goto :eof
)
setlocal
@rem Stop the services
net stop "Novell ZENworks Agent Service" 2>> error.log
net stop "Novell ZENworks Remote Management powered by VNC" 2>> error.log
net stop "Novell Identity Store" 2>> error.log
@rem kill the zombie process, if any
taskkill /F /IM ZenworksWindowsService.exe
taskkill /F /IM ZenNotifyIcon.exe
taskkill /F /IM ZenUserDaemon.exe
taskkill /F /IM nzrWinVNC.exe
taskkill /F /IM micasad.exe
@rem set the value of ZENWORKS_TARGET_DIR
call :getTargetDir %ZENWORKS_HOME%
@rem Install the MSI
msiexec -i "%~1" TARGETDIR="%ZENWORKS_TARGET_DIR%" REBOOT=ReallySuppress ALLUSERS=1 /lvx*+ "casa.msi.log" /qn
@rem Stop the services and kill the zombie process, if any
net stop "Novell Identity Store" 2>> error.log
taskkill /F /IM micasad.exe 2>> error.log
@rem Now install the MSI in repair mode
msiexec -i "%~1" TARGETDIR="%ZENWORKS_TARGET_DIR%" REBOOT=ReallySuppress ALLUSERS=1 REINSTALL=ALL REINSTALLMODE=vamus /lvx*+ "casa.msi.log" /qn
net start "Novell ZENworks Agent Service" 2>> error.log
net start "Novell ZENworks Remote Management powered by VNC" 2>> error.log
net start "Novell Identity Store" 2>> error.log
start "" /B "%ZENWORKS_HOME%\bin\ZenNotifyIcon.exe"
goto :eof
@rem subroutine to extract ZENWORKS_TARGET_DIR
:getTargetDir
set NOVELL_ZENWORKS_DIR=%~dp1
if not exist "%NOVELL_ZENWORKS_DIR%ZENworks" goto PATHOK
SET NOVELL_ZENWORKS_DIR=%NOVELL_ZENWORKS_DIR:~0,-1%
:PATHOK
call :getParent %NOVELL_ZENWORKS_DIR%
goto :eof
:getParent
set ZENWORKS_TARGET_DIR=%~dp1
goto :eof